Foros Windows

Hola, me gustaría que alguien me diera una buena noticia contestándome que sí se puede hacer lo siguiente:

El caso es que me gustaría poner en el menú inicio un vínculo al la carpeta "Mis videos" igual que se puede hacer con las carpetas "Mi música" y "Mis imágenes". Mejor mirar este pantallazo:
http://img364.imageshack.us/my.php?image=inicionm6.png

La opción para ponerlo está en "Propiedades" del menú inicio (pinchando con el botón secundario), pestaña "Menú inicio", "personalizar", pestaña "Opciones avanzadas" y "Elementos del menú inicio":
http://img119.imageshack.us/my.php?image=elementosqb8.png

La opción para poner las carpetas "Mi música" y "Mis imágenes" sí sale, así como la carpeta "Mis documentos" (salen en la lista de "Elementos del menú inicio"). Pero no hay ninguna opción para poner la carpeta "Mis videos".
La pregunta es ¿conoce alguien alguna manera de poner ahí, en esa zona del menú inicio, un vínculo a la carpeta "Mis videos"? Sería muy útil para mi y me ahorraría bastante tiempo.

Espero haberme explicado bien. Gracias y un saludo.

Bienvenido al foro!
Mira debajo de Ejecutar si esto responde a lo que necesitas. En caso afirmativo y, si no hay otra propuesta mejor, esta noche te lo explico (ahora voy mal de tiempo)

Saludos

Aunque no sea eso lo que pretende, a mí sí me lo explicas, que no sabía que se puede hacer eso.

Me apunto en la lista de los que desean saberlo

Estimado público: sin olvidar a jahorcaji; pero especialmete dedicadas a esa magnífica persona que está detras del alias Cubano, y al bueno de robert_dll vamos a deleitarles con un par de melodías:

Cómo crear un vínculo OEM

El vínculo OEM es un espacio que ha reservado Microsoft en el Registro de sus sistemas para que los fabricantes puedan anclar en la lanzadera de Inicio aplicaciones propias, enlaces publicitarios y otras monsergas.
Como no podía ser de otra manera, los miles de hjp que pululan por Internet lo han aprovechado también para, cuando ingenuamente entramos en una página que promete verificar la integridad de nuestro Registro, endilgarnos avisitos imborrables del tipo "Su sistema está infectado, pulse aquí para..."
Poe el contrario, nosotros, vamos aprovecharlo para noble causa.
Se trata, en definitiva, de realizar una adición al Registro y para no complicarnos vamos a aprovecharnos de uno de los múltiples scripst creados por el infatigable Doug Knox.
A tal fin (lo de siempre):
Copia en bloc de notas el texto que a continuación te pongo en azul. Guárdalo en Escritorio con cualquier nombre (oemlink, por ejemplo); pero antes de dar en Guardar como pulsa sobre Tipo para que en lugar de *.txt muestre Todos los archivos. Ahora, ya sídamos en Guardar como y lo guardas como oemlink.vbs

'lowersmfolderadd.vbs - Adds a folder under the Run command on the
'New XP Start Menu
'© 2003 - Kelly Theriot and Doug Knox

Option Explicit
On Error Resume Next

'Declare variables
Dim WSHShell, p1, t
Dim jobfunc, SMText, SMPath

'Set the Windows Script Host Shell and assign values to variables
Set WSHShell = WScript.CreateObject("WScript.Shell")

SMText = Inputbox("Enter the text you want to appear on the Start Menu.","Entry name","Enter Text Here")

If SMText = "" Then
WScript.Quit
End If

SMPath = Inputbox("Enter the path to the folder.","Enter Folder path","C:\Documents and Settings")

If SMPATH = "" Then
WScript.Quit
End If

p1 = "HKCR\CLSID\{2559a1f6-21d7-11d4-bdaf-00c04f60b9f0}\"

WSHShell.RegWrite p1, SMText
WSHShell.RegWrite p1 & "Infotip", SMPath
WSHShell.RegWrite p1 & "DefaultIcon\","%systemroot%\system32\shell32.dll,4"
WSHShell.RegWrite p1 & "InProcServer32\","%systemroot%\system32\shdocvw.dll", "REG_EXPAND_SZ"
WSHShell.RegWrite p1 & "InProcServer32\ThreadingModel","Apartment"
WSHShell.RegWrite p1 & "Instance\CLSID","{3f454f0e-42ae-4d7c-8ea3-328250d6e272}"
WSHShell.RegWrite p1 & "Instance\InitPropertyBag\CLSID","{13709620-C279-11CE-A49E-444553540000}"
WSHShell.RegWrite p1 & "Instance\InitPropertyBag\Command","&Open"
WSHShell.RegWrite p1 & "Instance\InitPropertyBag\method","ShellExecute"
WSHShell.RegWrite p1 & "Instance\InitPropertyBag\Param1",SMPath
WSHShell.RegWrite p1 & "shellex\ContextMenuHandlers\{2559a1f6-21d7-11d4-bdaf-00c04f60b9f0}\",""
WSHShell.RegWrite p1 & "shellex\MayChangeDefaultMenu\",""
WSHShell.RegWrite p1 & "ShellFolder\Attributes",0,"REG_DWORD"
WSHShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\StartMenu\StartPanel\ShowOEMLink\NoOEMLinkInstalled",0,"REG_DWORD"

Set WshShell = Nothing

'Describe the funtion of the script for a dialog box

jobfunc = SMText & vbcr & SMPath & vbcr & "Has been added to the Start Menu" & vbCR & vbcr
jobfunc = jobfunc & "Log off/log on to see the changes."

t = "Confirmation"
MsgBox jobfunc, 4096, t

Ahora nos dirijimos a la carpeta que queremos enlazar y creamos un acceso directo en el Escritorio con el fin de obtener más fácilmente su ruta completa, le pedimos Propiedades y copiamos el contenido completo de la ventana Destino. en el caso que nos ocupa:
"C:\Documents and Settings\Usuario\Mis documentos\Mis vídeos"

Pues, bien, doble clic sobre oemlink.vbs y se nos abrirá una primera ventana donde escribiremos el texto que luego aparecerá debajo del icono en Inicio (Mis videos, Videos, Pelis...en fin, lo que querais). Pulsamos Aceptar y tendremos una segunda ventana. En ella pegamos la ruta completa (comillas incluidas) que antes habíamos copiado ("C:\Documents and Settings\Usuario\Mis documentos\Mis vídeos")
pulsamos en Aceptar, reiniciamos el equipo y...
tema despachado.

Cómo deshacer un vículo OEM

Sucede habitualemte que llega un momento en que ese acceso directo en Inicio, ya no nos interesa, nos aburre...en una palabra, queremos volver a la ortodoxia servil de Microsoft.
Ahora explicaremos cómo deshacer un vínculo OEM creado por nosotros ó alevosamente insertado en nuestro sistema por gente indeseable (esta será la segunda melodía, que cierra la verbena).

Copia en bloc de notas el texto que te pongo en azul. Guárdalo en Escritorio con cualquier nombre (deshacerOEM, por ejemplo); pero antes de dar en Guardar como pulsa sobre Tipo para que en lugar de *.txt muestre Todos los archivos. Ahora, ya sí, lo guardas como deshacerOEM.reg.

Windows Registry Editor Version 5.00

[-HKEY_CLASSES_ROOT\CLSID\{2559a1f6-21d7-11d4-bdaf-00c04f60b9f0}]

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\StartMenu\StartPanel\ShowOEMLink]
"NoOEMLinkInstalled"=dword:00000001

Doble clic sobre ese archivo, aceptas, reinicias el equipo y tema concluido.

Añadir, por último, que si eres un poco curioso, a poco que investigues en esa clave del Registro, se te ocurrirá otras opciones (como por ejemplo, cambiar el icono, en lazar con una Web tec)


Cordiales saludos a todos.

Y ahora, ¿cómo le cuento yo que de mayor quiero ser Señor del Mal y conquistar el Universo?

Me anoto el truco, esperando impaciente la segunda parte.

Sus deseos han sido cumplidos. Se ha editado y ampliado el post inicial.

Saludos

Guardado en mis favoritos y en mi equipo por si algo vuelve a ocurrir con el foro (esperemos que no ).

Gracias Souto

Bueníssimo el truco!! hecho y funcionando!!
me he quedado flipao muy muy bueno.

Y para rizar el rizo, ¿podría ponerse ese link (ese acceso directo) que hemos creado, colocado justo debajo de "mis imagenes" y "mi musica" en el menú inicio? es decir, que no aparezca ahí abajo del todo de la lista. ¿?

Qué de secretillos que se guarda el majete windows...

Gracias Souto, eres un maki.

ah, y otra pregunta: una vez hecho el vínculo OEM, ¿se pueden borrar los 2 archivos que hemos creado en el escritorio (el oemlink.vbs y el acceso directo)? ¿funcionará igualmente si borramos esos dos archivos?